[Tabellenname$]
     [Tabellenname$A1:C5]
     [Tabellenname$A2:A2]

     DAO 3.5x  ->  ['Tabellenname mit Leerzeichen'$]
     DAO 3.6   ->  ['Tabellenname mit Leerzeichen$']

Public Function GetDataFromWkb_DAO(ByVal strDBName As String, _
      ByVal strSQL As String, ByVal fColHDR As Boolean, _
      ByRef avarDataXL() As Variant) As Boolean

  Dim dbsDAO        As DAO.Database
  Dim rstDAO        As DAO.Recordset
  Dim strConnect    As String

  Dim nFieldsCnt    As Long
  Dim nRecordsCnt   As Long

  Dim nFld          As Long
  Dim nRec          As Long

  Dim blnData       As Boolean

  strConnect = "Excel 8.0;"
  If Not fColHDR Then
    strConnect = strConnect & "HDR=No;"
  End If

  On Error GoTo err_GetValues

  Set dbsDAO = DBEngine.OpenDatabase( _
        strDBName, False, True, strConnect)

  Set rstDAO = dbsDAO.OpenRecordset(strSQL)
  With rstDAO
    If Not (.EOF Or .BOF) Then
      .MoveLast:  .MoveFirst

      nFieldsCnt = .Fields.Count - 1
      nRecordsCnt = .RecordCount - 1

      ReDim avarDataXL(0 To nRecordsCnt, 0 To nFieldsCnt)

      nRec = 0
      On Error Resume Next
      Do While Not .EOF
        For nFld = 0 To nFieldsCnt
          If Not IsNull(.Fields(nFld).Value) Then
            If IsDate(.Fields(nFld).Value) Then
              avarDataXL(nRec, nFld) = _
                  Format$(.Fields(nFld).Value, "yyyy-mm-dd")
            Else
              avarDataXL(nRec, nFld) = .Fields(nFld).Value
            End If
            blnData = True
          End If
        Next
        nRec = nRec + 1
        .MoveNext
      Loop
      On Error GoTo 0

      If blnData Then
          GetDataFromWkb_DAO = True
      Else
          MsgBox "Der Quellbereich enthält keine Daten!", _
               vbInformation, "VB-fun-Demo"
      End If

    Else
      MsgBox "Keine entsprechenden Datensätze gefunden!", _
           vbInformation, "VB-fun-Demo"
    End If
  End With

exit_Func:
  On Error Resume Next

  rstDAO.Close
  Set rstDAO = Nothing
  dbsDAO.Close
  Set dbsDAO = Nothing

  On Error GoTo 0
  Exit Function

err_GetValues:
  MsgBox "Fehler " & Err.Number & vbCrLf & Err.Description, _
        vbCritical, "VB-fun-Demo"
  Resume exit_Func
End Function

Public Sub Start_GetDataFromWkb_DAO()
  Dim strDBName     As String
  Dim strSource     As String
  Dim strSQL        As String
  Dim avarDataXL()  As Variant

  Dim optXLCalcMode As Long

  Dim wksDest       As Worksheet
  Dim nColDest      As Integer
  Dim nRowDest      As Long

  strDBName = ThisWorkbook.Path & "\TestDateien\Mappe1.xls"
  strSource = "[Tabelle1$]"
  strSQL = "SELECT * FROM " & strSource & ";"

  If Len(Dir$(strDBName)) = 0 Then
    MsgBox "Die Datei " & vbCrLf & strDBName & vbCrLf & _
          "existiert nicht!", vbInformation, "VB-fun-Demo"
    Exit Sub
  End If

  If GetDataFromWkb_DAO(strDBName, strSQL, True, avarDataXL()) Then
    With Application
      optXLCalcMode = .Calculation
      .Calculation = xlManual
      .EnableEvents = False
    End With

    nColDest = 1
    Set wksDest = ActiveWorkbook.Worksheets(1)

    On Error Resume Next
    With wksDest
      If Application.WorksheetFunction.CountA(.Cells) > 0 Then
        nRowDest = .Cells.Find(What:="*", After:=.Cells(1, 1), _
                    SearchOrder:=xlByRows, _
                    SearchDirection:=xlPrevious).Row + 1
      Else
          nRowDest = 2
      End If

      Err.Clear
      .Cells(nRowDest, nColDest).Resize( _
            UBound(avarDataXL, 1) + 1, _
            UBound(avarDataXL, 2) + 1).Value = avarDataXL

      If Err.Number = 0 Then
        .UsedRange.Columns.AutoFit

        MsgBox "Die Daten aus dem Quellbereich '" & strSource & _
            "' wurden eingelesen!", vbInformation, "VB-fun-Demo"

      Else
        MsgBox "Fehler " & Err.Number & vbCrLf & _
              Err.Description, vbCritical, "VB-fun-Demo"
      End If
    End With

    Erase avarDataXL
    Set wksDest = Nothing

    With Application
      .EnableEvents = True
      .Calculation = optXLCalcMode
    End With
  End If
  On Error GoTo 0
End Sub