Tipp 0343 Daten in DataGrid anzeigen (ADO)
Autor/Einsender:
Datum:
  Markus Schutz
09.07.2003
Entwicklungsumgebung:   VB 6
Dieser Tipp zeigt wie man die Daten einer Tabelle in einer Access-Datenbank in einem DataGrid-Steuerelement anzeigen kann.
 
Option Explicit

Private objConn As ADODB.Connection
Private rsMain  As ADODB.Recordset

Private Sub Form_Load()
  Dim strPath As String

  On Error GoTo err_Handler

  strPath = App.Path
  If Right$(strPath, 1) <> "\" Then strPath = strPath & "\"

  Set objConn = New ADODB.Connection
  Set rsMain = New ADODB.Recordset

  With objConn
    .Provider = "Microsoft Jet 4.0 OLE DB Provider"
    .ConnectionString = "Data Source=" & strPath & "datenbank.mdb"
    .Open
  End With

  With rsMain
    .ActiveConnection = objConn
    .CursorLocation = adUseClient
    .Source = "SELECT * FROM tbl_Adressen"
    .Open
  End With

  Set dbgAdressen.DataSource = rsMain

  With dbgAdressen
    .BorderStyle = dbgNoBorder
    .Columns("ID").Width = 400
    .Columns("Ort").Width = 1800
  End With

exit_Sub:
  On Error GoTo 0
  Exit Sub

err_Handler:
  MsgBox "Fehlernummer " & Err.Number & Chr$(13) & Error$(Err), _
            vbCritical, "Fehler"

  Resume exit_Sub
End Sub

Private Sub Form_Terminate()
  On Error Resume Next

  rsMain.Close
  Set rsMain = Nothing

  objConn.Close
  Set objConn = Nothing

  On Error GoTo 0
End Sub
 
Hinweis
Um diesen Tipp ausführen zu können, muss die Microsoft ActiveX Data Objects 2.x Library in das Projekt eingebunden werden.

Windows-Version
95
98/SE
ME
NT
2000
XP
Vista
Win 7
VB-Version
VBA 5
VBA 6
VB 4/16
VB 4/32
VB 5
VB 6


Download  (22 kB) Downloads bisher: [ 3749 ]

Vorheriger Tipp Zum Seitenanfang Nächster Tipp

Startseite | Projekte | Tutorials | API-Referenz | VB-/VBA-Tipps | Komponenten | Bücherecke | VB/VBA-Forum | VB.Net-Forum | DirectX-Forum | Foren-Archiv | DirectX | VB.Net-Tipps | Chat | Spielplatz | Links | Suchen | Stichwortverzeichnis | Feedback | Impressum

Seite empfehlen Bug-Report
Letzte Aktualisierung: Samstag, 27. August 2011