Tipp 0261 Diagramm-Daten auslesen
Autor/Einsender:
Datum:
  Angie
24.04.2005 (Update)
Entwicklungsumgebung:   Excel 97
Mit folgender Prozedur werden die Werte der Datenreihen direkt aus einem bestehenden Diagramm ermittelt und in einem Tabellenblatt ausgegeben. Ein praktischer Einsatz zum Beispiel wäre, wenn die zu einem Diagramm gehörigen Daten nicht mehr zur Verfügung stehen, sei es weil die Arbeitsmappe, in der sich die Originaldaten befinden, abhanden gekommen oder beschädigt ist.
 
Option Explicit

Private Const mc_MsgTitle As String = _
      "VB-fun-Demo - Diagramm-Daten ermitteln"

Public Sub GetChartValues()
  Dim objWksDest  As Worksheet

  Dim objChart    As Chart
  Dim objSeries   As Series

  Dim nRowsCnt    As Long
  Dim nCol        As Integer

  If TypeName(Selection) = "ChartArea" Then
    Set objChart = ActiveChart
    If objChart.SeriesCollection.Count > 0 Then
      nRowsCnt = UBound(objChart.SeriesCollection(1).Values)

      Set objWksDest = Worksheets.Add(After:=ActiveSheet)
      With objWksDest
        .Range(.Cells(2, 1), .Cells(nRowsCnt + 1, 1)) = _
            Application.Transpose( _
            objChart.SeriesCollection(1).XValues)
      End With

      nCol = 2
      On Error Resume Next
      For Each objSeries In objChart.SeriesCollection
        With objWksDest
          .Cells(1, nCol) = objSeries.Name
          .Range(.Cells(2, nCol), .Cells(nRowsCnt + 1, nCol)) = _
                Application.Transpose(objSeries.Values)
        End With
        nCol = nCol + 1
      Next
      On Error GoTo 0
      Set objWksDest = Nothing

    Else
      MsgBox "Es sind keine Datenreihen vorhanden !", _
             vbOKOnly + vbInformation, mc_MsgTitle
    End If
    Set objChart = Nothing

  Else
    MsgBox "Bitte wählen Sie ein Diagramm aus !", _
           vbOKOnly + vbInformation, mc_MsgTitle
  End If
End Sub
 
Hinweis
Die im Download befindliche *.bas-Datei kann in Excel im VB-Editor importiert werden.
Weitere Links zum Thema
Diagramme auf UserForm anzeigen
Diagramme erstellen

Windows-Version
95
98/SE
ME
NT
2000
XP
Vista
Win 7
Excel-Version
95
97
2000
2002 (XP)
2003
2007
2010


Download  (2,1 kB) Downloads bisher: [ 1398 ]

Vorheriger Tipp Zum Seitenanfang Nächster Tipp

Startseite | Projekte | Tutorials | API-Referenz | VB-/VBA-Tipps | Komponenten | Bücherecke | VB/VBA-Forum | VB.Net-Forum | DirectX-Forum | Foren-Archiv | DirectX | VB.Net-Tipps | Chat | Spielplatz | Links | Suchen | Stichwortverzeichnis | Feedback | Impressum

Seite empfehlen Bug-Report
Letzte Aktualisierung: Sonntag, 26. Juni 2011