Tipp 0226 Internet-Verbindung prüfen und bestimmen
Autor/Einsender:
Datum:
  Detlev Schubert
14.04.2002
Entwicklungsumgebung:   VB 5
Mit der API-Funktion InternetGetConnectedState kann man recht einfach prüfen, ob der PC gerade mit dem Internet verbunden ist. Dabei gibt die Funktion zusätzlich auch noch die Art der Verbindung (über Modem, LAN oder Proxy-Server) zurück.
 
Option Explicit

Private Declare Function InternetGetConnectedState _
    Lib "wininet.dll" (ByRef lpdwFlags As Long, _
    ByVal dwReserved As Long) As Long

Private Const INTERNET_CONNECTION_MODEM As Long = &H1
Private Const INTERNET_CONNECTION_LAN As Long = &H2
Private Const INTERNET_CONNECTION_PROXY As Long = &H4
Private Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8
Private Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Private Const INTERNET_CONNECTION_CONFIGURED As Long = &H40
Private Const INTERNET_RAS_INSTALLED As Long = &H10

Private Sub Form_Load()
  Timer1.Interval = 100
End Sub

Private Sub Timer1_Timer()
  Dim dwflags As Long
  Dim sText As String
  Dim msg As String

  If InternetGetConnectedState(dwflags, 0&) Then

    If dwflags And INTERNET_CONNECTION_CONFIGURED Then
      msg = msg & _
          "Es ist eine Internetverbindung eingerichtet." & vbCrLf
    End If

    If dwflags And INTERNET_CONNECTION_LAN Then
      msg = msg & _
          "Die Internetverbindung erfolgt über ein Netzwerk"
    End If

    If dwflags And INTERNET_CONNECTION_MODEM Then
      msg = msg & "Die Internetverbindung erfolgt über ein Modem"
    End If

    If dwflags And INTERNET_CONNECTION_PROXY Then
      msg = msg & " mittels eines Proxy-Servers." & vbCrLf
    Else
      msg = msg & "." & vbCrLf
    End If

    If dwflags And INTERNET_CONNECTION_OFFLINE Then
      msg = msg & "Es besteht z.Zt. keine Internetverbindung. "
    End If

    If dwflags And INTERNET_CONNECTION_MODEM_BUSY Then
      msg = msg & "Das Modem nutzt z.Zt eine andere Verbindung. "
    End If

    If dwflags And INTERNET_RAS_INSTALLED Then
      msg = msg & _
          "Ein Remote Access Service (RAS) ist installiert. "
    End If

  Else
    msg = "Es besteht z.Zt. keine Internetverbindung."

  End If

  Label1.Caption = msg
End Sub
 
Weitere Links zum Thema
DFÜ-Status prüfen

Windows-Version
95
98/SE
ME
NT
2000
XP
Vista
Win 7
VB-Version
VBA 5
VBA 6
VB 4/16
VB 4/32
VB 5
VB 6


Download  (2,7 kB) Downloads bisher: [ 3524 ]

Vorheriger Tipp Zum Seitenanfang Nächster Tipp

Startseite | Projekte | Tutorials | API-Referenz | VB-/VBA-Tipps | Komponenten | Bücherecke | VB/VBA-Forum | VB.Net-Forum | DirectX-Forum | Foren-Archiv | DirectX | VB.Net-Tipps | Chat | Spielplatz | Links | Suchen | Stichwortverzeichnis | Feedback | Impressum

Seite empfehlen Bug-Report
Letzte Aktualisierung: Sonntag, 4. September 2011