Tipp 0210 Bearbeiten von Datensätzen (DAO)
Autor/Einsender:
Datum:
  Stephan Liebler
16.03.2002
Entwicklungsumgebung:   VB 5
Dieser Tipp zeigt, wie einfach und komfortabel es ist, mit dem DAO-Datenzugriffsmodell auf eine Access-Datenbank (Access 97) zugreifen zu können.
Code im Codebereich von Form1 - Datensätze einlesen
 
Option Explicit

Dim DB As Database
Dim Rst As Recordset

Public varName As String
Public varVName As String
Public alles As String

Private Sub Form_Load()
  Set DB = OpenDatabase(App.Path & "\Telefon.mdb")
  Set Rst = DB.OpenRecordset("Telefon")

  Rst.MoveFirst
  Do Until Rst.EOF
    lstNamen.AddItem Rst!Name & ", " & Rst!Vname
    Rst.MoveNext
  Loop

  lstNamen.Selected(0) = True
End Sub

Private Sub cmdNeu_Click()
  Form2.Show
  Unload Me
End Sub

Private Sub cmdAendern_Click()
  lstNamen_DblClick
End Sub

Private Sub lstNamen_DblClick()
  Dim pos As Integer

  alles = lstNamen.Text
  pos = InStr(1, alles, ", ")

  varName = Left(alles, pos - 1)
  varVName = Right(alles, Len(alles) - pos - 1)

  Form3.Show
  Unload Me
End Sub

Private Sub cmdEnde_Click()
  Unload Me
  End
End Sub

Private Sub Form_Unload(Cancel As Integer)
  DB.Close
  Set DB = Nothing
  Set Rst = Nothing
End Sub
 
Code im Codebereich von Form2 - Datensatz hinzufügen
 
Option Explicit

Dim DB As Database
Dim Rst As Recordset
Dim SQL As String

Private Sub Form_Load()
  Set DB = OpenDatabase(App.Path & "\Telefon.mdb")
  Set Rst = DB.OpenRecordset("Telefon")
End Sub

Private Sub cmdEintragen_Click()
  SQL = "INSERT INTO Telefon (Name, VName, Telefonnummer) " & _
            "VALUES ('" & txtName.Text & "', '" & _
            txtVName.Text & "', '" & txtNummer.Text & "')"

  DB.Execute (SQL)

  Form1.Show
  Unload Me
End Sub

Private Sub Form_Unload(Cancel As Integer)
  DB.Close
  Set DB = Nothing
  Set Rst = Nothing
End Sub
 
Code im Codebereich von Form3 - Datensatz ändern / löschen
 
Option Explicit

Dim DB As Database
Dim Rst As Recordset
Dim SQL As String
Dim varNummer As Long

Private Sub Form_Load()
  Set DB = OpenDatabase(App.Path & "\Telefon.mdb")

  SQL = "SELECT * FROM Telefon WHERE " & _
            "Name = '" & Form1.varName & "' AND " & _
            "VName = '" & Form1.varVName & "'"

  Set Rst = DB.OpenRecordset(SQL)

  varNummer = Rst!Telefonnummer

  txtName.Text = Rst!Name
  txtVName.Text = Rst!Vname
  txtNummer.Text = Rst!Telefonnummer
End Sub

Private Sub cmdOK_Click()
  SQL = "UPDATE Telefon SET " & _
            "Name = '" & txtName.Text & "', " & _
            "VName = '" & txtVName.Text & "', " & _
            "Telefonnummer = '" & txtNummer.Text & "' " & _
            "WHERE Telefonnummer = " & varNummer

  DB.Execute (SQL)

  Form1.Show
  Unload Me
End Sub

Private Sub cmdLoeschen_Click()
  SQL = "DELETE * FROM Telefon WHERE " & _
            "Name = '" & Form1.varName & "' AND " & _
            "VName = '" & Form1.varVName & "'"

  DB.Execute (SQL)

  Form1.Show
  Unload Me
End Sub

Private Sub Form_Unload(Cancel As Integer)
  DB.Close
  Set DB = Nothing
  Set Rst = Nothing
End Sub
 
Hinweis
Um diesen Tipp ausführen zu können, muss entweder die Microsoft DAO 3.51 Object Library oder die Microsoft DAO 3.6 Object Library als Verweis in das Projekt eingebunden werden.
Weitere Links zum Thema
Datenbank erstellen
Datensätze bearbeiten, suchen und drucken

Windows-Version
95
98/SE
ME
NT
2000
XP
Vista
Win 7
VB-Version
VBA 5
VBA 6
VB 4/16
VB 4/32
VB 5
VB 6


Download  (13,4 kB) Downloads bisher: [ 4605 ]

Vorheriger Tipp Zum Seitenanfang Nächster Tipp

Startseite | Projekte | Tutorials | API-Referenz | VB-/VBA-Tipps | Komponenten | Bücherecke | VB/VBA-Forum | VB.Net-Forum | DirectX-Forum | Foren-Archiv | DirectX | VB.Net-Tipps | Chat | Spielplatz | Links | Suchen | Stichwortverzeichnis | Feedback | Impressum

Seite empfehlen Bug-Report
Letzte Aktualisierung: Samstag, 6. August 2011