Imports System.Threading

Public Class Form1
  Dim HauptthreadContext As SynchronizationContext

  Private Sub Button1_Click(ByVal sender As System.Object, _
      ByVal e As System.EventArgs) Handles Button1.Click
    ' Kontext des Hauptthreads festhalten
    HauptthreadContext = SynchronizationContext.Current

    ' Nebenthread startet die Methode TMachtWas
    Dim T As New Thread(AddressOf TMachtWas)
        T.Start()
  End Sub

  Private Sub TMachtWas()
    ' Nebenthread läuft:
    ' Irgendwas ins Array berechnen
    Dim MyArr(19) As String

    For i As Integer = 0 To 19
      MyArr(i) = Rnd.ToString("#0.00000000")
    Next

    ' Methode ImHauptThread wird vom Hauptthread aufgerufen
    ' Array wird hier übergeben, ansonsten einfach Nothing
     HauptthreadContext.Post(New SendOrPostCallback(AddressOf _
       ImHauptThread), MyArr)
  End Sub

  Private Sub ImHauptThread(ByVal state As Object)
    ' Durch Hauptthread füllt sich die ListBox,
    ' daher ist kein Delegat & Invoke nötig
    ListBox1.Items.Clear()
    Dim myarr() As String = DirectCast(state, String())
    ListBox1.Items.AddRange(myarr)
  End Sub

  Private Sub Button2_Click(ByVal sender As System.Object, _
      ByVal e As System.EventArgs) Handles Button2.Click
    Me.Close()
  End Sub

End Class